domingo, 13 de diciembre de 2020

40 - Tarjetas animadas

 Esta época del año nos motiva a realizar otro tipo de trabajos en Excel, en este caso la creación de tarjetas festivas.

Los gifs animados son especiales para esto. Y para ello necesitaremos utilizar el control llamado Microsoft Web Browser.


NOTA: Si una vez dibujado el control en la hoja aparece un mensaje de que no este control no se encuentra habilitado, ver notas con aclaraciones en esta entrada o en el video 20 de mi canal.

El formato de la hoja (colores, fuente, tamaño de la tarjeta) queda a gusto de cada uno. 

En el video 40 cuyo enlace queda al pie se muestran 2 modelos: con o sin texto personalizado y con 1 sola hoja o como portada de un libro de más hojas.


Las macros que se necesitan son las siguientes:

En el objeto ThisWorkbook o Este Libro:

Private Sub Workbook_Open()

'seleccionar hoja de apertura y asignarle rango scroll

Sheets("Hoja1").Select          'esta instrucción solo si el libro contará con más de una hoja

ActiveSheet.[K8].Select

ActiveSheet.ScrollArea = "$A$1:$Q$40"

[F2] = ""   'quitar mensaje para habilitar macros

End Sub

En el objeto Hoja donde se colocará la tarjeta:

Private Sub Worksheet_Activate()

'web browser

  ruta = ThisWorkbook.Path           'ubicar la imagen en la misma carpeta que el libro

  archivo = "navidad2021-c"          

  ext = ".gif"

 

  WebBrowser1.Navigate _

  "about:<html><body scroll='no'><img src='" & _

  ruta & "\" & archivo & ext & _

  " '></img></body></html>"

End Sub


NOTA: las variables que componen el nombre del objeto imagen se pueden incluir en una cadena que luego se reemplazará por la instrucción de color azul en la macro anterior. Por ejemplo:


ruta = ThisWorkbook.Path  

archivo = "navidad2021-c.gif"    


o también: 

ruta = ThisWorkBook.Path\navidad2021-c.gif


Eventualmente, si contamos con un libro con más de una hoja, podremos dibujar un botón para que nos ingrese al resto de la aplicación. Para ello insertaremos un módulo donde colocaremos la instrucción que seleccionará la hoja de trabajo que corresponda.


Sub INGRESO()

Sheets("PORTADA").Select

End Sub


Descargar los 2 archivos del ejemplo: Libro.xlsm e imagen.

Ver Video 40 desde aquí.


















sábado, 31 de octubre de 2020

39 - RowSource o cómo actualizar desplegables desde otro formulario.

 Ya hemos visto en video N° 9 cómo utilizar macros o procesos desde diferentes ámbitos o llamadas.

Ahora veremos cómo actualizar un control desplegable que tenemos en nuestro userform abierto cuando la lista se actualiza desde otro formulario. Sin necesidad de cerrarlo y volverlo a abrir.

En el video 39 dejo 3 ejemplos: 

Ej 1- solicitando el nuevo elemento de la lista desde un InputBox.
Nuestro desplegable tendrá asignado el rango a mostrar, desde la propiedad RowSource (no desde el código).

Una vez ingresado el texto en el InputBox se procede a volcarlo a la lista en modo mayúscula.


Private Sub CommandButton1_Click()             'nueva caja

'solicita nuevo nombre (en mayúsculas)

caja = UCase(InputBox("Ingresar nuevo Tipo."))

'si el InputBox queda vacío

If caja = "" Then

    ComboBox2.SetFocus

Else

'agrega a la hoja Listas       'verificar q no se duplique (*)

    With Sheets("Listas")

        .Range("E" & .Range("E" & Rows.Count).End(xlUp).Row + 1) = caja

    End With

                                       

'actualizar el control         'ordenar previamente (**)

    ComboBox2.RowSource = "=cajas"

    ComboBox2.Text = caja

    'opcional: pasarle el foco a algún otro control

    ComboBox4.SetFocus

End If

End Sub


NOTA: las macros para evitar duplicados y ordenar la lista se encuentran en el libro de descarga, en formularios del modelo N° 2.

Ej 2: solicitando el nuevo nombre desde otro Userform con un control TextBox:
En este caso dejamos vacía la propiedad RowSource del control desplegable. Se lo alimentará con el método AddIem desde el evento Initialize del formulario, recorriendo la columna de datos que se encuentra en una hoja (Listas).

Private Sub UserForm_Initialize()

x = Sheets("Listas").Range("A" & Rows.Count).End(xlUp).Row

If x > 2 Then

    For i = 3 To x

        ComboBox1.AddItem Sheets("Listas").Range("A" & i)

    Next i

End If

End Sub


Private Sub CommandButton3_Click()       'nueva marca

'llamar al segundo formulario

UF_ProdMarcas.Show

'al regresar ya se habrá dejado en el control Combobox el texto ingresado

If ComboBox1 <> "" Then

    'guardarlo provisoriamente en una variable

    dato = ComboBox1.Text

    'ordenar la lista

    Call ordenaLISTAS

    'vaciar el combo para actualizarlo nuevamente con la lista actualizada

    ComboBox1.Clear

    For i = 3 To Sheets("Listas").Range("A" & Rows.Count).End(xlUp).Row

        ComboBox1.AddItem Sheets("Listas").Range("A" & i)

    Next i

    'volver a mostrar el dato guardado

    ComboBox1 = dato

End If

End Sub


En el segundo formulario, el botón GUARDAR tendrá el siguiente código:

Private Sub CommandButton2_Click()       

UF_Prod.ComboBox1 = TextBox1     'lo muestra en el control

Unload UF_ProdMarcas 

End Sub 


NOTA: el código completo, con el control para evitar duplicados y macro de ordenamiento se encuentra en el libro de descarga.

Ej 3: llamando a un segundo formulario común a otros procesos.
En este tercer ejemplo, el desplegable se alimenta con la propiedad RowSource declarada en el evento Initialize del formulario principal.

Como en el segundo formulario es posible actualizar la lista con más de un elemento, al cerrarlo se deja vacío el desplegable para realizar la selección.

Private Sub UserForm_Initialize()

filx = Sheets("Listas").Range("C1").CurrentRegion.Rows.Count

ComboBox2.RowSource = "=Listas!C3:C" & filx

End Sub

 

Private Sub CommandButton4_Click()

'se selecciona la primer opción del 2do formulario, dándole el foco al control de texto

UF_VerificaListas.OptionButton1.Value = True

UF_VerificaListas.TextBox1.SetFocus

'se llama al 2do formulario

UF_VerificaListas.Show

'al regresar se actualiza el control combobox con el nuevo rango

ComboBox2.RowSource = "=Listas!C3:C" & Sheets("Listas").Range("C1").CurrentRegion.Rows.Count

             End Sub 

NOTA: el botón de guardado del segundo formulario debe realizar el control de duplicados. Es opcional ordenar la lista desde ese formulario o al regresar al formulario principal (códigos que se encuentran en formulario del modelo N° 2)

Descarga libro completo desde aquí.

Ver Video N° 39 desde aquí.

sábado, 17 de octubre de 2020

38 - Funciones de Conversión para controles TextBox.

Frecuentemente se encuentran consultas acerca de 'errores' al trabajar con controles del tipo TextBox. Errores que no son tales si recordamos que esos controles guardan su información en formato 'Texto'.

Así por ejemplo, en el Video 38 se muestra la comparación entre 2 controles:

TextBox3 = "537"   TextBox5 = "1032"

Si TextBox3 < TexBox5 -------> pinte el control de rojo .... pero veremos que no se pinta. Porque entre textos el primero es mayor.

Por lo tanto, ya sea para realizar cálculos entre estos controles y datos de la hoja o para realizar comparaciones se necesitará convertirlos al formato número según se requiera.

1 - Función VAL: convierte un texto en un valor numérico:

      "537"  ------->  537

      "1432" ------>  1432

Pero si enviamos un valor numérico con decimales a un control TextBox, la función VAL truncará la parte decimal mostrando solamente la parte entera.

Por ejemplo: TextBox3 = 537,40      celda = 1430,50

Al realizar una suma:  suma = VAL(TextBox3) + celda = 537 + 1430,50 =  1957,50 (lo correcto: 1967,90)

2 - Función CDBL: convierte 'texto' con decimales a valor numérico con decimales.

Por ejemplo: TextBox3 = 537,40      TextBox5= 1430,50

Al realizar una suma:  suma = CDBL(TextBox3) + CDBL(TextBox5)

                                     suma = 537,40 + 1430,50 =  1967,90)

IMPORTANTE: La función CDBL dará error si se intenta convertir el contenido de un control vacío. Por lo tanto habrá que contemplar ese posible error, siendo los siguientes ejemplos algunos de los modos posibles.

Ejemplo 1: colocando una instrucción On Error antes de manipular ese control vacío:

'colorear según condición del resultado

On Error Resume Next

If CDbl(TextBox3) < TextBox5.Value Then

    TextBox5.BackColor = &HFF&                  '< rojo

ElseIf CDbl(TextBox3) = Range("G" & filx).Value Then

    TextBox5.BackColor = &H80FF&                '=naranja

Else

    TextBox5.BackColor = &HFFFF&                '> amarillo

End If

Ejemplo 2: evaluar si el control está vacío y en ese caso tomar otra decisión. En este ejemplo se coloca 1 en la celda, sino el valor convertido del control TextBox16:

If TextBox16 <> "" Then

    hox.Range("K" & fily) = CDbl(TextBox16)

Else

    hox.Range("K" & fily) = 1

End If


Ver VIDEO N° 38

viernes, 16 de octubre de 2020

37 - Protección en Excel: libros, hojas y estructura.

 En el siguiente video se muestran las diferentes opciones de protección que nos ofrece Excel:

Video 37

A continuación algunas instrucciones de protección:

1 - Apertura y guardado de Libros:

Sub abreProtegido()

'para abrir libro con contraseña de apertura

nbreLibro = ThisWorkbook.Path & "\Gestoria01.xlsm"

Application.Workbooks.Open nbreLibro, Password:="elsa"

'otro modo de escribir la misma instrucción

Application.Workbooks.Open nbreLibro, , , , "elsa"

End Sub

 

Sub abreEscritura()

'para abrir libro con contraseña de escritura

nbreLibro = ThisWorkbook.Path & "\Gestoria02.xlsm"

Application.Workbooks.Open nbreLibro, WriteResPassword:="yo", Password:="elsa"

'otro modo de escribir la misma instrucción

Application.Workbooks.Open nbreLibro, , , , "elsa", "yo"

End Sub

 

Sub abreSoloLectura()

'para abrir libro como solo lectura

nbreLibro = ThisWorkbook.Path & "\Gestoria03.xlsm"

Application.Workbooks.Open nbreLibro, ReadOnly:=True

'otro modo de escribir la misma instrucción

Application.Workbooks.Open nbreLibro, , True

End Sub

 

Sub guardaProtegido()

'para guardar libro con un nombre distinto al libro activo

nbreLibro = ThisWorkbook.Path & "\Gestoria03.xlsm"

ActiveWorkbook.SaveAs Filename:=nbreLibro, Password:="elsa"

'para guardar libro con el mismo nombre, pero con clave

ActiveWorkbook.SaveAs Password:="miclave"

End Sub

2 - Protección de Hojas:

Sub protegeHoja()

'para Desproteger una hoja con clave

Sheets(1).Unprotect "clave"

'para proteger con clave y algunos permisos

Sheets(1).Protect "clave", DrawingObjects:=True, Contents:=True, Scenarios:=True _

        , AllowFormattingCells:=True, AllowFormattingColumns:=True, _

        AllowFormattingRows:=True, AllowSorting:=True, AllowFiltering:=True, _

        AllowUsingPivotTables:=True

End Sub

3 - Protección de Estructura del libro. Esto permite inhabilitar la opción de crear, quitar o renombrar hojas de un libro.

Sub protegeLibro()

'desprotege la estructura del libro

ActiveWorkbook.Unprotect "tu"

'protege estructura con clave

 ActiveWorkbook.Protect "tu", Structure:=True, Windows:=False

End Sub


viernes, 4 de septiembre de 2020

Filtros dinámicos con VBA, utilizando Userform

En el video anterior (N° 34) vimos cómo realizar una búsqueda dinámica directamente desde la hoja, utilizando Filtros Avanzados.

Hoy vamos a seguir con el tema, pero en esta ocasión utilizando un formulario o Userform.

En esta entrega encontrarán 2 ejemplos y en ambos el resultado de la búsqueda se muestra en un control ListBox.

Ejemplo 1: Desde un control TextBox se ingresará el texto a buscar en TODA la hoja, no importando en qué columna se encuentre. El resultado se irá mostrando en el control Lista.  La búsqueda se realiza de modo parcial, es decir que las celdas deben contener el texto buscado.  

Además este modelo presenta un control Combobox para realizar búsqueda por Nombre completo. A medida que se van registrando las letras se filtrará la lista.


En este formulario programamos 3 eventos. Initialize (o sea al iniciar el formulario), TextBox_Change y ComboBox_Change en el caso de que además del control TextBox se cuenta con un desplegable también.

Ejemplo 2: En este modelo se utilizarán tantos controles TextBox como criterios tengamos para la búsqueda. Cada control corresponderá a una columna de la tabla. El resultado se irá mostrando en el control Listbox de modo filtrado. Los criterios se solicitan como: contenido en celdas de col A y C y coincidencia total con la columna B. 


Tanto en la apertura del formulario (evento Initialize) como desde el botón 'Limpiar' (CommandButton1_Click), se mostrará la lista completa en el control ListBox. 

El resto del código será para los 3 controles TextBox (evento Change) o la cantidad que tenga el formulario. Cada uno de estos eventos, luego de filtrar el rango correspondiente según su columna, llama a una macro común para el llenado del ListBox.

Los criterios para las columnas A y C se buscan de modo parcial, como parte del contenido de las celdas. En cambio para la columna B la coincidencia debe ser total.

Por ejemplo, para el primer TextBox:

Private Sub TextBox11_Change()
If TextBox11 <> "" Then
dato1 = "*" & TextBox11.Value & "*"         
Range("$A$3:$G$" & Range("A" & Rows.Count).End(xlUp).Row).AutoFilter Field:=1, Criteria1:=dato1, Operator:=xlAnd
Else
ActiveSheet.Range("$A$3:$G$" & Range("A" & Rows.Count).End(xlUp).Row).AutoFilter Field:=1
End If
Call llenalista
End Sub

Sub llenalista()
ListBox1.Clear
x = Range("A" & Rows.Count).End(xlUp).Row
If x < 4 Then Exit Sub
For Each cd In Range("A4:A" & x).SpecialCells(xlCellTypeVisible)
ListBox1.AddItem cd.Value
i = ListBox1.ListCount - 1
ListBox1.List(i, 1) = Range("B" & cd.Row)
ListBox1.List(i, 2) = Range("C" & cd.Row)
Next cd
End Sub

 

Ver VIDEO 36.

Desde el siguiente enlace se puede descargar el libro con la programación de los ejemplos, tanto del video 35 como del 36:

http://aplicaexcel.com/Blog/FiltroAvanzado.xlsm

 



 

martes, 18 de agosto de 2020

Filtros Avanzados con VBA

 Generalmente utilizamos un formulario o Userform destinado a búsquedas de información.

Pero si buscamos algo sencillo estos 2 ejemplos nos servirán: filtrar tablas de datos dinámicamente, es decir que a medida que escribimos los criterios o los seleccionamos ya vamos obteniendo el filtrado de los datos.

Ejemplo 1:  A medida que se escriben los criterios en un rango destinado a tal fin, la tabla se irá filtrando.

El proceso se ejecuta en el evento Change de la hoja donde se encuentra esta tabla. Y llama a una subrutina llamada 'filtrando' que se encuentra en un módulo.

      Private Sub Worksheet_Change(ByVal Target As Range)
      'se controla lo ingresado en rango de criterios
      If Intersect(Target, Range("$A$2:$C$2")) Is Nothing Then Exit Sub
      On Error Resume Next
      Call filtrando
      End Sub

      Sub filtrando()
      'establecer fin de rango.
      filas = [A6].CurrentRegion.Rows.Count + 3
      'se incrementa en 3 por ser la cantidad de filas por encima del rango
      Range("A6:G" & filas).AdvancedFilter Action:=xlFilterInPlace, _
          CriteriaRange:=Range("A1:C2")
      End Sub

Para quitar el filtrado se borran las celdas de criterio (A2:C2)

Ejemplo 2: Se colocan las celdas de criterios en un rango auxiliar. Se ejecutará a medida que se vayan seleccionando celdas con los criterios elegidos de cada columna. La macro volcará el valor de la selección a las celdas de criterios del Filtro Avanzado para luego ejecutar el filtrado.

En este ejemplo, el proceso se ejecuta al seleccionar una celda de las columnas A:C. Por lo tanto el código se colocará en la hoja a trabajar, evento Selection_Change.

      Private Sub Worksheet_SelectionChange(ByVal Target As Range)
      'solo se ejecuta cuando se seleccione alguna celda en columnas A:C, a partir de la fila 4
      If Target.Column > 3 Or Target.Row < 4 Then Exit Sub
      'según en qué columna se hizo la selección se volcará ese contenido al rango de criterios
      If Target.Column = 1 Then [J2] = Selection.Value
      If Target.Column = 2 Then [K2] = Selection.Value
      If Target.Column = 3 Then [L2] = Selection.Value
      'llama a macro de filtrado
      Call filtrandoAux
      End Sub

    Sub filtrandoAux()
    'x Elsamatilde
    'establecer fin de rango
    filas = [A6].CurrentRegion.Rows.Count
    Range("A3:G" & filas).AdvancedFilter Action:=xlFilterInPlace, _
        CriteriaRange:=Range("J1:L2")
    End Sub

Para quitar el filtrado bastará con seleccionar alguna celda vacía dentro de las columnas A:C para que esas celdas vacías se vuelquen al rango de criterios.
Ahora, si la tabla es muy extensa (y no se visualizan filas vacías) se podría llamar al menú Datos, Filtros, Borrar.  Pero como desde esa opción no se quitarán los criterios y esto puede llevar a cierta confusión, lo mejor será ejecutar la siguiente macro desde el menú Desarrollador:

      Sub quitaFiltros()
      'para quitar los filtros, borrar primero los criterios
       [J2:L2] = ""
      ActiveSheet.ShowAllData
      End Sub

Ver VIDEO 35.

Desde el siguiente enlace se puede descargar el libro con la programación de los ejemplos, tanto del video 35 como del 36:

http://aplicaexcel.com/Blog/FiltroAvanzado.xlsm

 

viernes, 24 de abril de 2020

Abrir documentos vinculados desde Excel

En la entrada anterior (Hipervínculos-vínculos) vimos cómo guardar hipervínculos a sitios web, desde un control de Userform, y así poder llamarlos haciendo clic en la celda que contendrá ese enlace.
También vimos cómo vincular archivos de imagen a registros de una base de cualquier índole. Esta opción nos permite luego insertar esas imágenes en otros procesos Excel.
En esos casos utilizamos las instrucciones Hyperlink.Add y GetOpenFilename respectivamente.

Ahora vamos a ver cómo guardar nombre y dirección de documentos asociados a registros de una base. Utilizaremos nuevamente estas 2 instrucciones anteriores.
Además veremos otra macro para abrir esos archivos vinculados con un simple atajo de teclado. La instrucción utilizada será: FollowHyperlink.

Para ello partimos de una hoja base donde tendremos códigos e información de documentos y una columna para guardar el nombre del mismo (en pdf, doc o cualquier otro formato). Además guardaremos la ubicación de esos archivos en otra columna o en una celda auxiliar.

Utilizaré un Userform con controles para rellenar las columnas de datos, un botón para BUSCAR el archivo asociado y 2 botones de guardado, ya sea que guardemos la ubicación como hipervínculo (se llamará desde el mismo enlace) o la guardaremos separando nombre del archivo y su ruta. Luego tendremos una macro para llamar y abrir el documento elegido.
La macro del botón BUSCAR será la siguiente:
Private Sub CommandButton11_Click()    'BUSCAR
miDoc = Application.GetOpenFilename(Title:="Selecciona tu archivo")
'si la variable está vacía significa que cancelamos la ventana de diálogo
If miDoc = False Then
    TextBox2 = ""
Else
    TextBox2 = miDoc
End If
End Sub

Para GUARDAR los registros tendremos 2 opciones: como hipervínculo o como nombre+ubicación del archivo.
Private Sub CommandButton1_Click()   'GUARDAR con hipervínculo
With Sheets("Hoja3")
    x = .Range("A" & Rows.Count).End(xlUp).Row + 1
    .Range("A" & x) = Application.WorksheetFunction.Max(.Range("A:A")) + 1
    .Range("B" & x) = TextBox1
    .Range("C" & x) = ComboBox2
    .Range("D" & x) = ComboBox1
    .Range("E" & x) = TextBox2
    'hipervínculo en celda col E
    If TextBox2 <> "" Then _
        .Hyperlinks.Add Anchor:=.Range("E" & x), Address:=.Range("E" & x).Value, _
            ScreenTip:="ver doc", TextToDisplay:=.Range("E" & x).Value
End With
'limpia controles para un nuevo registro
ComboBox1.ListIndex = -1: ComboBox2.ListIndex = -1
TextBox1 = "": TextBox2 = ""
TextBox1.SetFocus
End Sub

Private Sub CommandButton2_Click()   'guardar solo nbre archivo
    With Sheets("Hoja3")
    x = .Range("A" & Rows.Count).End(xlUp).Row + 1
    .Range("A" & x) = Application.WorksheetFunction.Max(.Range("A:A")) + 1
    .Range("B" & x) = TextBox1
    .Range("C" & x) = ComboBox2
    .Range("D" & x) = ComboBox1
    'guardar nbre de archivo
    .Range("E" & x) = Dir(TextBox2)     'solo nombre del archivo
    'obtener la ruta
    '.Range("F" & x) = Left(TextBox2, InStr(1, TextBox2, Dir(TextBox2)) - 1)
End With
'limpia controles para un nuevo registro
ComboBox1.ListIndex = -1: ComboBox2.ListIndex = -1
TextBox1 = "": TextBox2 = ""
TextBox1.SetFocus
End Sub
En caso de haber guardado la ubicación del archivo relacionado como hipervínculo no necesitaremos ninguna macro para abrir ese documento. Con hacer clic sobre la celda de la col E será suficiente.
En cambio si guardamos el nombre+ubicación podemos llamarlos desde la siguiente macro. Para mayor comodidad le asignamos un atajo de teclado.
La macro se ubica en un módulo y se ejecutará estando seleccionada alguna celda de la col B y que no esté vacía.

Sub abriendoArchivo()
'ATAJO DE TECLADO: CTRL f
'solo se ejecuta con celda seleccionada en col B
If ActiveCell.Column <> 2 Or ActiveCell = "" Then Exit Sub
'asignamos la ruta o carpeta donde se encuentran los PDF.
'Optar por una de las 3 instrucciones
'ruta = ThisWorkbook.Path & "\ESCANEADOS\"   'en subcarpeta del libro activo
ruta = [F1]                                                                   'en celda auxiliar F1
'ruta = ActiveCell.Offset(0, 4)                                    'en col F del registro
On Error Resume Next
ActiveWorkbook.FollowHyperlink ruta & ActiveCell.Offset(0, 3)
End Sub

'otra opción podría ser evaluar si col F está vacía y en ese caso tomar la ruta indicada en F1.
'If ActiveCell.Offset(0, 4) = "" Then
    'ruta = [F1]
'Else
   ' ruta = ActiveCell.Offset(0, 4)
'End If

Descargar libro de ejemplos desde aquí
Ver VIDEO 34.

jueves, 16 de abril de 2020

Hipervínculos - Vínculos

En esta entrada veremos cómo dejar hipervínculos para acceder a sitios web. También aprenderemos a vincular nuestros datos en Excel con otros archivos (imágenes, pdf, etc) para ser llamados desde otros procesos.

CASO 1:
Desde una hoja Excel, llenaremos una tabla de temas que vincularemos a sitios web.

Se trabajará con un formulario o Userform, donde pegaremos la dirección del sitio en un control TextBox. Luego al guardar el contenido de los controles en la hoja, en la col E además le insertaremos el hipervínculo con el siguiente código.

La instrucción será: nombre_de_hoja.HYPERLINKS.ADD

Private Sub CommandButton1_Click()   'GUARDAR
With Sheets("UF-Sitios")
    x = .Range("A" & Rows.Count).End(xlUp).Row + 1
    .Range("A" & x) = Application.WorksheetFunction.Max(.Range("A:A")) + 1
    .Range("B" & x) = ComboBox1
    .Range("C" & x) = ComboBox2
    .Range("D" & x) = TextBox1
    .Range("E" & x) = TextBox2
    'hipervínculo en celda col E
    .Hyperlinks.Add Anchor:=.Range("E" & x), Address:=.Range("E" & x).Value, _
        TextToDisplay:="ver sitio"
End With
'limpia controles para un nuevo registro
ComboBox1.ListIndex = -1: ComboBox2.ListIndex = -1
TextBox1 = "": TextBox2 = ""
ComboBox1.SetFocus
End Sub

CASO 2:
En una hoja Excel tendremos una tabla de productos, con todos sus datos en diferentes columnas añadiendo una columna para el nombre de la imagen asociada y otra para la ruta de esa imagen vinculada.
Esta opción será de utilidad para crear catálogos, recetarios y todos aquellos informes donde además de datos debiera mostrarse una imagen relacionada.
En el formulario tendremos 2 controles para la imagen: un TextBox para guardar la ruta completa y un control IMAGE donde mostrar la imagen.

El botón BUSCAR nos permitirá navegar por el equipo para encontrar la imagen a vincular. Se puede filtrar la búsqueda indicando algunas extensiones como jpg o bmp.
Nota: no será posible presentar un archivo 'png' en un control Image.

Para la búsqueda utilizaremos el método GETOPENFILENAME.
Para separar solo el nombre del archivo la instrucción DIR.
Para obtener solo la ruta se extrae del texto completo solo la parte hasta el inicio del nombre del archivo con las funciones: LEFT INSTR

El código completo del botón BUSCAR es el siguiente:
Private Sub CommandButton11_Click()
mifoto = Application.GetOpenFilename("Formato(*.jpg; *.bmp),*.jpg; *.bmp", Title:="Selecciona tu imagen")
'si la variable está vacía significa que cancelamos la ventana de diálogo
If mifoto = False Then
    TextBox25 = ""
Else
    Image1.Picture = LoadPicture(mifoto)
    nbreFoto = Dir(mifoto)     'nbre de la foto
    rutax = Left(mifoto, InStr(1, mifoto, nbreFoto) - 1)
    TextBox25 = rutax
End If
End Sub

Al GUARDAR, además del contenido de los controles se guardará el nombre del archivo guardado en la variable (nbreFoto) que se declara al inicio del Userform para que pueda ser utilizada en las 2 subrutinas
Esto se logra con la instrucción:  Dim nbreFoto As String  


Dim hoi                    'nbre de la hoja declarada en el evento Initialize
Dim nbreFoto As String     'nbre de la foto

Private Sub CommandButton1_Click()   'GUARDAR
'completo col datos fijos
ini = hoi.Range("A2").End(xlDown).Row + 1
hoi.Range("A" & ini) = ComboBox1
hoi.Range("B" & ini) = TextBox1

'guarda nbre y ruta de la imagen
hoi.Range("E" & ini) = nbreFoto
hoi.Range("F" & ini) = TextBox25

'limpia el UF para un nuevo ingreso
ComboBox1.ListIndex = -1
TextBox1 = "": TextBox25 = ""
Image1.Picture = LoadPicture("")
ComboBox1.SetFocus
End Sub

El guardar imágenes asociadas a una base de productos nos permitirá armar luego un catálogo, con otro proceso que las ubicará y dimensionará en las celdas correspondientes. Por ejemplo:


Descargar el libro con formularios completos desde aquí.

Ver VIDEOS 32  y  33.